home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 4 NO 1.st / POGOSRC.ARC / STPUTDOT.ASM < prev    next >
Encoding:
Assembly Source File  |  1985-11-20  |  3.3 KB  |  221 lines
  1.  
  2.     dseg
  3.     public _cscreen
  4.     public _bitmasks
  5.     public _in_graphics
  6.  
  7.     cseg
  8.  
  9.     ;getdot(x, y)
  10.     ;    return color in cscreen at x,y
  11.     public _getdot
  12.     public getdot
  13. _getdot    move.w    4(sp),d0
  14.     move.w    6(sp),d1
  15. getdot    move.l    _cscreen,a0 
  16.     lsl.w    #5,d1
  17.     adda.w    d1,a0
  18.     add.w    d1,d1
  19.     add.w    d1,d1
  20.     adda.w    d1,a0    ;effectively multiply y coordinate by 160 = 128+32
  21.     move.w    d0,d1    ;copy of x coordinate in d1
  22.     and.w    #$fff0,d1    
  23.     lsr.w    #1,d1
  24.     adda    d1,a0    ; point a0 to the right word even ... 
  25.     move.l    #_bitmasks,a1
  26.     and.w    #$000f,d0    ; find place in word
  27.     add.w    d0,d0    ;convert to word index
  28.     move.w    0(a1,d0.w),d1    ;  now have mask in d1
  29.     clr.w    d0    ; start out color 0
  30.     move.w    (a0)+,d2
  31.     and.w    d1,d2
  32.     beq    not1
  33.     or.w    #1,d0
  34. not1    move.w    (a0)+,d2
  35.     and.w    d1,d2
  36.     beq    not2
  37.     or.w    #2,d0
  38. not2    move.w    (a0)+,d2
  39.     and.w    d1,d2
  40.     beq    not4
  41.     or.w    #4,d0
  42. not4    move.w    (a0)+,d2
  43.     and.w    d1,d2
  44.     beq    not8
  45.     or.w    #8,d0
  46. not8    rts
  47.  
  48.  
  49.     ;    putdot(x, y, color)
  50.     ;        fast one dot on screen
  51.     public _putdot
  52. _putdot
  53.     move.w    6(sp),d0    ; get y coordinate
  54.     bmi        putdotz
  55.     cmp.w    #200,d0
  56.     bge        putdotz
  57.     move.l    _cscreen,a0
  58.     lsl.w    #5,d0
  59.     adda.w    d0,a0
  60.     add.w    d0,d0
  61.     add.w    d0,d0
  62.     adda.w    d0,a0    ; effectively multiply y coordinate by 160 = 128+32
  63.     move.w    4(sp),d0    ; get x coordinate
  64.     bmi        putdotz
  65.     cmp.w    #320,d0
  66.     bge        putdotz
  67.     move.w    d0,d1
  68.     and.w    #$fff0,d1    
  69.     lsr.w    #1,d1
  70.     adda    d1,a0    ; point a0 to the right word even ... 
  71.     move.l    #_bitmasks,a1
  72.     and.w    #$000f,d0    ; find place in word
  73.     add.w    d0,d0    ;convert to word index
  74.     move.w    0(a1,d0.w),d0    ;  now have mask in word
  75.     move.w    8(sp),d1    ; get color parameter
  76.     and.w    #15,d1        ; make sure it's a legal value
  77.     add.w    d1,d1
  78.     add.w    d1,d1        ;convert to pointer value
  79.     move.l    #dots,a1
  80.     move.l    0(a1,d1.w),a1    ; get rest of routine for this color
  81.     jmp        (a1)
  82. putdotz    rts
  83.  
  84.  
  85. dot0:    
  86.     not.w    d0
  87.     and.w    d0,(a0)+
  88.     and.w    d0,(a0)+
  89.     and.w    d0,(a0)+
  90.     and.w    d0,(a0)+
  91.     rts
  92.  
  93. dot1: 
  94.     or.w    d0,(a0)+
  95.     not.w    d0
  96.     and.w    d0,(a0)+
  97.     and.w    d0,(a0)+
  98.     and.w    d0,(a0)+
  99.     rts
  100.  
  101. dot2: 
  102.     or.w    d0,2(a0)
  103.     not.w    d0
  104.     and.w    d0,(a0)
  105.     and.w    d0,4(a0)
  106.     and.w    d0,6(a0)
  107.     rts
  108.  
  109. dot3:
  110.     or.w    d0,(a0)+
  111.     or.w    d0,(a0)+
  112.     not.w    d0
  113.     and.w    d0,(a0)+
  114.     and.w    d0,(a0)+
  115.     rts
  116.  
  117. dot4:
  118.     or.w    d0,4(a0)
  119.     not.w    d0
  120.     and.w    d0,(a0)+
  121.     and.w    d0,(a0)
  122.     addq    #4,a0
  123.     and.w    d0,(a0)
  124.     rts
  125.  
  126. dot5:
  127.     or.w    d0,(a0)
  128.     or.w    d0,4(a0)
  129.     not.w    d0
  130.     and.w    d0,2(a0)
  131.     and.w    d0,6(a0)
  132.     rts
  133.  
  134. dot6:
  135.     or.w    d0,2(a0)
  136.     or.w    d0,4(a0)
  137.     not.w    d0
  138.     and.w    d0,(a0)
  139.     and.w    d0,6(a0)
  140.     rts
  141.  
  142. dot7:
  143.     or.w    d0,(a0)+
  144.     or.w    d0,(a0)+
  145.     or.w    d0,(a0)+
  146.     not.w    d0
  147.     and.w    d0,(a0)+
  148.     rts
  149.  
  150. dot8:    
  151.     not.w    d0
  152.     and.w    d0,(a0)+
  153.     and.w    d0,(a0)+
  154.     and.w    d0,(a0)+
  155.     not.w    d0
  156.     or.w    d0,(a0)
  157.     rts
  158.  
  159. dot9: 
  160.     or.w    d0,(a0)+
  161.     or.w    d0,4(a0)
  162.     not.w    d0
  163.     and.w    d0,(a0)+
  164.     and.w    d0,(a0)
  165.     rts
  166.  
  167. dota: 
  168.     or.w    d0,2(a0)
  169.     or.w    d0,6(a0)
  170.     not.w    d0
  171.     and.w    d0,(a0)
  172.     and.w    d0,4(a0)
  173.     rts
  174.  
  175. dotb:
  176.     or.w    d0,(a0)+
  177.     or.w    d0,(a0)+
  178.     or.w    d0,2(a0)
  179.     not.w    d0
  180.     and.w    d0,(a0)
  181.     rts
  182.  
  183. dotc:
  184.     not.w    d0
  185.     and.w    d0,(a0)+
  186.     and.w    d0,(a0)+
  187.     not.w    d0
  188.     or.w    d0,(a0)+
  189.     or.w    d0,(a0)
  190.     rts
  191.  
  192. dotd:
  193.     or.w    d0,(a0)
  194.     or.w    d0,4(a0)
  195.     or.w    d0,6(a0)
  196.     not.w    d0
  197.     and.w    d0,2(a0)
  198.     rts
  199.  
  200. dote:
  201.     or.w    d0,2(a0)
  202.     or.w    d0,4(a0)
  203.     or.w    d0,6(a0)
  204.     not.w    d0
  205.     and.w    d0,(a0)
  206.     rts
  207.  
  208. dotf:
  209.     or.w    d0,(a0)+
  210.     or.w    d0,(a0)+
  211.     or.w    d0,(a0)+
  212.     or.w    d0,(a0)
  213.     rts
  214.  
  215.  
  216.     dseg
  217. dots dc.l     dot0,dot1,dot2,dot3,dot4,dot5,dot6,dot7
  218.     dc.l    dot8,dot9,dota,dotb,dotc,dotd,dote,dotf
  219.  
  220.  
  221.